2.7 :childindex()

Mit Hilfe dieser Methode kann man den absoluten Index eines Kindes in einem Treeview berechnen lassen. Dazu übergibt man dieser Methode den relativen Index des Kindes bezüglich seines Vaters.

Definition 

integer :childindex
(
  integer Parent input,
  integer Child  input
)

Parameter

integer Parent input
In diesem Parameter wird der Index des Vaters angegeben.
integer Child input
In diesem Parameter wird der Index des Kindes bezüglich dem angegebenen Vater angegeben.

Rückgabewert

0
Bei einem Fehler.
> 0
Absoluter Index des Kindes.

Objekte mit dieser Methode

treeview

Beispiel 

window Wn
{
  .title "Beispiel fuer die Methode :childindex()";
  child treeview Tv
  {
    .content[1] "Firma A";
    .content[2] "Mueller";
    .content[3] "Meier";
    .content[4] "Firma B";
    .content[5] "Schulz";
    .content[6] "Schmidt";
    .content[7] "Fischer";
    .style[style_lines]   true;
    .style[style_buttons] true;
    .style[style_root]    true;
    .level[2] 2;
    .level[3] 2;
    .level[5] 2;
    .level[6] 2;
    .level[7] 2;
  }

  child pushbutton PbIn
  {
    .text "Bestimme absolute Nummer";
    on select
    {
      variable integer I := Tv:childindex(Tv.activeitem, atoi(EtIn.content));

      if fail(atoi(EtIn.content)) then
        St.text := "Haben sie einen Mitarbeiter eingegeben?";
      endif
      if (I = 0) then
        St.text := "Haben sie eine Firma selektiert?";
      else
        St.text := itoa(I);
      endif
    }
  }

  child edittext EtIn
  {
    .content   "Wievielter Mitarbeiter der selektierten Firma?";
    .multiline true;
  }

  child statictext St
  {
    .text "Ergebnis der Anfrage";
  }
}