delete()

11.9 delete()

This function can be used to delete one or more values from a collection (data types hash, list, matrix, refvec and vector) at a given position. The subsequent values are shifted forward. The data type string is also supported to remove characters from a string.

The values are deleted at the specified position. The position must be >= 1, i.e. it is not possible to delete default values at the indices [0] or [0,0] with this function. The largest possible position is the current countof(ListValue).

The number of values to be deleted is determined by the Count parameter and should be >= 0.

In case of an error, the function call is aborted with a fail.

Also considered an error is the attempt to delete more values respectively rows or columns than actually exist.

Definition

anyalue delete
(
      anyvalue ListValue input
      integer  Pos   input
  { , integer  Count := 1 input }
  { , enum     Dir   := dir_row input }
)

Parameters

anyvalue ListValue input: This parameter specifies the collection or string where values shall be deleted.
integer Pos input: In this parameter, the index position is defined at which inclusively deleting begins. Values >= 1 are permitted. For matrix collections, depending on the Dir parameter, Pos represents either a row position (dir_row) or a column position (dir_column).
integer Count := 1 input: This optional parameter indicates the number of values (respectively rows or columns for a matrix) to be deleted. Values >= 0 are allowed, with no deleting being performed for 0. The number should not exceed the possible position range when deleting.
enum Dir := dir_row input: This optional parameter defines the orientation of the index position, which is important for a matrix. The default value dir_row means that rows are deleted in the matrix. With dir_column columns are deleted.

Return value

The function returns the modified collection respectively the modified string.

Particularities

hash

Since this collection data type does not have a defined index range, deleting takes place based on the integer indices. Thus a hash with an indexing of 1,2,3… is assumed. There are no limitations concerning the largest possible index position.
matrix

Deleting in a matrix always happens by rows or columns. This is controlled by the Dir parameter. By default (dir_row) rows are deleted. If dir_column is specified, columns are deleted. This also means that the position refers to a row in the first case and to a column in the second. The matrix is reduced accordingly.
string

Here the position refers to the character position in the string, i.e. the string is treated as an array of characters.

Examples

Multiple deletion of values from a list

variable list L := [17, "x", window, .xleft, null];
print delete(L, 2, 3);

Output

[17,null]

Deleting a column from a matrix

variable matrix M := [ [0,0]=>"?", [1,1]=>"a1", [1,2]=>"b1",
                       [2,2]=>"b2", [2,3]=>"c2" ];
M := delete(M, 2, dir_column);
print M;
print countof(M);

Output

[[1,1]=>"a1",[1,2]=>"?",[2,1]=>"?",[2,2]=>"c2"]
[2,2]

Removing two characters from a string
```
print delete("hello", 3, 2);
```
Output
```
"heo"
```

Deleting items from a hash with integer indexing

variable hash H := [2=>.xleft, 31=>.width, 33=>.ytop];
H := delete(H, 30, 3);
print H;

Output

[2=>.xleft,30=>.ytop]

Deleting from a vector list

variable vector[boolean] V := [true, false, false, false, true];
print delete(V, 2, 3);

Output

[true,true]

Deleting the first two items from a refvec list

variable refvec R := [PbApply, PbCancel, PbRevert];
print delete(R, 1, 2);

Output

[pushbutton D.PbRevert]

Availability

Since IDM version A.06.02.g