11.9 delete()

anyalue delete
(
      anyvalue ListValue input
      integer  Pos   input
  { , integer  Count := 1 input }
  { , enum     Dir   := dir_row input }
)

Parameter

anyvalue ListValue input

In diesem Parameter wird die Sammlung bzw. der String angegeben aus der Werte gelöscht werden sollen.

integer Pos input

In diesem Parameter wird die Indexposition angegeben, ab der einschließlich das Löschen erfolgen soll. Erlaubt sind Werte >= 1. Bei matrix-Sammlungen stellt Pos je nach Dir-Parameter entweder eine Zeilenposition (dir_row) oder eine Spaltenposition (dir_column) dar.

integer Count := 1 input

In diesem optionalen Parameter wird die Anzahl der Werte (bzw. Zeilen oder Spalten bei einer Matrix) vorgegeben, die zu löschen sind. Erlaubt sind Werte >= 0, wobei bei 0 kein Löschen erfolgt. Durch die Anzahl sollte beim Löschen der mögliche Positionsbereich nicht überschritten werden.

enum Dir := dir_row input

In diesem optionalen Parameter wird die Ausrichtung der Indexposition definiert, was für eine Matrix von Bedeutung ist. Dabei bedeutet der Standardwert dir_row, dass in der Matrix Zeilen gelöscht werden. Bei dir_column werden Spalten gelöscht.

Rückgabewert

Die Funktion gibt die veränderte Sammlung bzw. den veränderten String zurück.

Besonderheiten

• hash

  Da dieser Sammlungsdatentyp keinen definierten Indexbereich besitzt, erfolgt das Löschen bezogen auf die integer-Indizes. Es wird also von einem hash mit einer Indizierung von 1,2,3… ausgegangen. Es gibt keine Beschränkungen hinsichtlich der größtmöglichen Indexposition.

• matrix

  Das Löschen in einer Matrix erfolgt immer zeilen- oder spaltenweise. Die Steuerung erfolgt über den Dir-Parameter. Standardmäßig (dir_row) werden Zeilen gelöscht. Bei Angabe von dir_column werden Spalten gelöscht. Dies bedeutet auch, dass sich die Positionsangabe im ersten Fall auf eine Zeile und im zweiten Fall auf eine Spalte bezieht. Entsprechend verkleinert sich damit auch die Matrix.

• string

  Hier bezieht sich die Position auf die Zeichenposition im String, d.h. der String wird als Array von Zeichen behandelt.

Beispiele

• Mehrfaches Löschen von Werten aus einer Liste

  variable list L := [17, "x", window, .xleft, null];
  print delete(L, 2, 3);

  Ausgabe

  [17,null]

• Löschen einer Spalte aus einer Matrix

  variable matrix M := [ [0,0]=>"?", [1,1]=>"a1", [1,2]=>"b1",
                         [2,2]=>"b2", [2,3]=>"c2" ];
  M := delete(M, 2, dir_column);
  print M;
  print countof(M);

  Ausgabe

  [[1,1]=>"a1",[1,2]=>"?",[2,1]=>"?",[2,2]=>"c2"]
  [2,2]

• Entfernen von zwei Zeichen aus einem String

  print delete("hallo", 3, 2);

  Ausgabe

  "hao"

• Löschen von Elementen aus einem Hash mit integer-Indizierung

  variable hash H := [2=>.xleft, 31=>.width, 33=>.ytop];
  H := delete(H, 30, 3);
  print H;

  Ausgabe

  [2=>.xleft,30=>.ytop]

• Löschen aus einer vector-Liste

  variable vector[boolean] V := [true, false, false, false, true];
  print delete(V, 2, 3);

  Ausgabe

  [true,true]

• Löschen der ersten beiden Elemente aus einer refvec-Liste

  variable refvec R := [PbApply, PbCancel, PbRevert];
  print delete(R, 1, 2);

  Ausgabe

  [pushbutton D.PbRevert]

Verfügbarkeit

Ab IDM-Version A.06.02.g

Siehe auch

Eingebaute Funktion insert()