11.22 insert()

anyalue insert
(
      anyvalue ListValue  input,
      integer  Pos   input
  { , integer  Count := 1 input }
  { , enum     Dir   := dir_row input }
  { , anyvalue NewValue   input }
)

Parameter

anyvalue ListValue input

In diesem Parameter wird die Sammlung bzw. der String angegeben in die ein Wert eingefügt werden soll.

integer Pos input

In diesem Parameter wird die Indexposition angegeben, vor der das Einfügen erfolgen soll. Erlaubt sind Werte >= 1. Bei matrix-Sammlungen stellt Pos je nach Dir-Parameter entweder eine Zeilenposition (dir_row) oder eine Spaltenposition (dir_column) dar.

integer Count := 1 input

In diesem optionalen Parameter wird die Anzahl angegeben, wie oft ein neuer Wert (bzw. wie viele Zeilen oder Spalten) eingefügt werden soll. Erlaubt sind Werte >= 0, wobei bei 0 kein Einfügen erfolgt.

enum Dir := dir_row input

In diesem optionalen Parameter wird die Ausrichtung der Indexposition definiert, was für eine Matrix von Bedeutung ist. Dabei bedeutet der Standardwert dir_row, dass in der Matrix Zeilen eingefügt werden. Bei dir_column werden Spalten eingefügt.

anyvalue NewValue input

Dieser optionale Parameter definiert den neu einzufügenden Wert. Der Wert muss zum Wertetyp der Sammlung passen.

Rückgabewert

Die Funktion gibt die veränderte Sammlung bzw. den veränderten String zurück.

Besonderheiten

• hash

  Da dieser Sammlungsdatentyp keinen definierten Indexbereich besitzt, erfolgt das Einfügen bezogen auf die integer-Indizes. Es wird also von einem hash mit einer Indizierung von 1,2,3… ausgegangen. Es gibt keine Beschränkungen hinsichtlich der größtmöglichen Indexposition.

• matrix

  Das Einfügen in eine Matrix erfolgt immer zeilen- oder spaltenweise. Die Steuerung erfolgt über den Dir-Parameter. Standardmäßig (dir_row) werden neue Zeilen eingefügt. Bei Angabe von dir_column werden neue Spalten eingefügt. Dies bedeutet auch, dass sich die Positionsangabe im ersten Fall auf eine Zeile und im zweiten Fall auf eine Spalte bezieht.

• refvec

  Das Einfügen von null-Objekten ist nicht erlaubt. Ein mehrfaches Einfügen wird eben so wenig unterstützt, da die gleiche Objekt-Id nur einmal vorhanden sein darf. Falls die Objekt-Id schon vorhanden ist, erfolgt ein Umpositionieren.

• string

  Hier bezieht sich die Position auf die Zeichenposition im String, d.h. der String wird als Array von Zeichen behandelt.

• Default-Werte

  Grundsätzlich macht es Sinn beim Einfügen einen neuen Wert anzugeben. Wird dieser weggelassen, so hängt es vom Sammlungstyp ab, welche Werte an den eingefügten Positionen stehen. Die Sammlungstypen list, hash und matrix erlauben Default-Werte, sodass beim Einfügen ohne neuen Wert die Default-Werte an den eingefügten Positionen erscheinen.

Beispiele

• Mehrfaches einfügen des Strings "X" in eine Liste

  variable list L := ["a", "b", "c"];
  print insert(L, 1, 2, "X");

  Ausgabe

  ["X","X","a","b","c"]

• Anhängen einer Zeile an das Ende einer Matrix

  variable matrix M := [ [0,0]=>"?", [1,1]=>"a1", [1,2]=>"b1",
                         [2,1]=>"a2", [2,2]=>"b2" ];
  M := insert(M, 3, "NEW");
  print M;

  Ausgabe

  [[1,1]=>"a1",[1,2]=>"b1",[2,1]=>"a2",[2,2]=>"b2",[3,1]=>"NEW",[3,2]=>"NEW"]

  Einfügen einer neuen 1. Spalte ohne Wert

  M := insert(M, 1, dir_column);
  print M;

  Ausgabe

  [[1,1]=>"?", [1,2]=>"a1",[1,3]=>"b1",[2,1]=>"?",[2,2]=>"a2",[2,3]=>"b2",
  [3,1]=>"?",[3,2]=>"NEW",[3,3]=>"NEW"]

• Einfügen von "ll" in einen String

  print insert("hao", 3, 2, "l");

  Ausgabe

  "hallo"

• Einfügen in ein Hash mit integer-Indizierung

  variable hash H := [2=>.xleft, 33=>.ytop];
  H := insert(H, 10, .width);
  print H;

  Ausgabe

  [2=>.xleft,10=>.width,34=>.ytop]

• Einfügen in eine vector-Liste

  variable vector[boolean] V := [true, true];
  print insert(V, 2, 3, false);

  Ausgabe

  [true,false,false,false,true]

• Einfügen eines schon vorhandenen refvec-Elements an einer anderen Stelle

  variable refvec R := [PbApply, PbCancel, PbRevert];
  print insert(R, 1, PbRevert);

  Ausgabe

  [pushbutton D.PbRevert,pushbutton D.PbApply,pushbutton D.PbCancel]

Verfügbarkeit

Ab IDM-Version A.06.02.g

Siehe auch

Eingebaute Funktionen append(), delete()